Parameters in AMPL

1. Description
2. Declaring a Parameter
3. Parameter Types
4. Parameter Bounds
5. Default Values
6. Defining a Parameter
7. Accessing a Parameter

Description

Parameters hold "hard" values in AMPL. The values of parameters can be defined and changed in AMPL, but a solver will not change them while looking for an optimal solution.

Return to top

Declaring a Parameter

AMPL parameters are created in a similar way to AMPL variables, using the param keyword followed by a label.

param <my param name>; 

Example

param MinProtein; 

Like variables parameters are often defined over a set and may have several attributes:

param  <my param name>[{<(optional) indexing set>}] [<(optional) bounds, default values>]; 

Example

param ProteinPercent {INGREDIENTS} >= 0 <= 100; 

Return to top

Parameter Types

Parameters have the same possible types as variables. However, since parameter values are defined (not searched for), declaring a parameter type means that AMPL will ensure that the parameter is only ever assigned that type of data. For example, you cannot assign an integer parameter the value 1.5. This behaviour is very useful for automatically checking the validity of data files.

Return to top

Parameter Bounds

As well as using parameter types to check the validity of data, real and integer parameters can also have bounds set during their declaration. These bounds will be checked by AMPL any time the value of the parameter changes and, if they are violated, an error will be generated.

Example

param counter integer >= 0; 
let counter := -1; # This generates an error as counter is < 0

Return to top

Default Values

Default parameter values can be used to quickly set a large number of parameter values automatically. If a parameter is used without being explicitly assigned a value the default value is used for that parameter. AMPL uses a default value of 0 if no default value is given.

Example

set DIGITS := 1..5;
param isok {DIGITS} binary default 1;
let isok[3] := 0;

display {i in DIGITS} isok[i]; 

# Result
# ======
# isok[i] [*] :=
# 1  1
# 2  1
# 3  0
# 4  1
# 5  1
# ;

The AMPL macros Infinity and -Infinity are useful as defaults for parameters that act as bounds ( Infinity as a default upper bound, 0 or -Infinity as a default lower bound).

Return to top

Defining a Parameter

Once a parameter has been declared it is usually defined in a data file. This is done simply for a single value using the assignment operator :=:

param MinProtein := 8.0 ; 

For parameters declared over a 1-dimensional set this can be done using default values and a list for those parameters that don't take default values:

model;

param Min {REQUIREMENTS} default -Infinity;

data;

param Min :=
PROTEIN 8.0
FAT     6.0
  ;

Defining 2-Dimensional Parameters

In a similar way to 2-dimensional sets, there are three different ways to define 2-dimensional parameters.

1. Using a List For any parameter values that don't take the default value, you list the set element and value for that parameter.

model;
param Min {ARCS} integer, default 0;
data;
param Min :=
Youngstown 'Kansas City' 1000
Pittsburgh 'Kansas City' 2000
Cincinnati Albany 1000

1. Using a Table To define parameter data in a table format you use the param keyword and the parameter's name followed by the : operator, a list of the second index set elements followed by the := operator, then rows of the table with an element of the first index set followed by the values corresponding to the second index set's element in that column.

param : ... := ... ... ... ;

If the element does not exist or the default value is correct then place a . in the table. Otherwise, put the parameter value.

param Cost:
Cincinnati 'Kansas City' Chicago Albany Houston Tempe Gary :=
Youngstown 350 450 375 500 . . .
Pittsburgh 350 450 400 . . . 450
Cincinnati . . . 350 550 . .
'Kansas City' . . . . 375 650 .
Chicago . . . . . 600 120 ;

You can also define parameter data in a transposed table using almost the same syntax, but with the (tr) keyword and reversing the indexing sets

param (tr) : ... := ... ... ... ;

1. Using an Array You define a list of column indices and values for each row index.

param Cost :=
[Youngstown, *] Cincinnati 350 'Kansas City' 450 ... ...
[Chicago, *] ... Gary 120 ;

Note The row indices have [=} and =] around them (as opposed to ( and ) for sets).

Defining Multi-Dimensional Parameters

Since we have multi-dimensional sets, we might need multi-dimensional parameters, e.g., Cost {TIME_ARCS} has four dimensions. We can define these parameters in a similar way to multi-dimensional sets:

1. Using a List

   param Cost :=
   Youngstown April Albany April 0.5 # = 500 / 1000
   Youngstown April Youngstown May 0.015 # = 15 / 1000 ... ;
   

2. Using a Table

   param Cost :=
   [*, May, *, May] Cincinnati 'Kansas City' Albany ... :=
   Youngstown 0.35 0.45 0.5 ...
   Pittsburgh 0.35 0.45 . ... ... ;

Notice the [ ] around *, May, *, May as opposed to the ( ) for sets!

1. Using an Array

   set TIME_ARCS := (*, May, *, May) (Youngstown, Cincinnati) 0.35 ... ; 

   or

   set TIME_ARCS := (Youngstown, May, *, May) Cincinnati 0.35 'Kansas City' 0.45 ... ... ; 

Defining Multiple Parameters

Using the : operator, multiple parameters may be defined at once. Simply state the names of the parameters and the := operator. Then list the set elements and values on the following rows.

param:             ... :    ...    ...  ;

If a parameter is not defined or the default value is sufficient, use the . operator.

model;
 # The lower and upper bounds on the requirements
param Min {REQUIREMENTS} default -Infinity;
param Max {REQUIREMENTS} default Infinity;

data;
param:        Min Max:=
PROTEIN      8.0     .
FAT          6.0     .
FIBRE          .   2.0
SALT           .   0.4  ;

This approach also works for 2-dimensional parameters and lists, for the American Steel problem this allows us to "cut-and-paste" the list of arc properties

From node	To node	Cost	Minimum	Maximum
Youngstown	Albany	500	-	1000
Youngstown	Cincinnati	350	-	3000
Youngstown	Kansas City	450	1000	5000
Youngstown	Chicago	375	-	5000
etc

becomes

param:                   Cost  Min  Max:=
Youngstown Cincinnati     350    0 3000
Youngstown 'Kansas City'  450 1000 5000
...
Chicago    Gary           120    0 4000  ;

Return to top

Accessing a Parameter

Parameter values are accessed by specifying the indices of the parameter you want to access within [ and ].

Examples

See Cost and Contributes below.

# Objective: minimise the cost per (100g) can
minimize TotalCost: sum {i in INGREDIENTS} Cost[i] * Amount[i];

# Constraints: Meet the nutritional requirements

 subject to MeetRequirement {r in REQUIREMENTS}:
   Min[r] <= sum {i in INGREDIENTS} Contributes[i, r] * Amount[i] <= Max[r];

Return to top

-- MichaelOSullivan - 02 Mar 2008