Variables in AMPL

1. Description
2. Declaring a Variable
3. Variable Types
4. Variable Bounds
5. Initial Values
6. Default Values
7. Accessing a Variable
8. Examining Variables
9. Fixing Values

Description

AMPL variables are used to represent variables in mathematical programmes. They are quantities that a solver (e.g., CPLEX, MINOS) is allowed to change as it looks for a solution to the mathematical programme.

Return to top

Declaring a Variable

AMPL variables are created by using the var keyword and a label for the variable:

var <varname>; 

Example

var x1; 

Often, you will want to create one variable for every member (respectively pair, tuple) from a set (a two-dimensional set, multi-dimensional set, respectively). To do this you simply add the set after the variable name:

var <varname> [{<set>}]; 

Example

var Percentage {INGREDIENTS}; 

You can access the variable corresponding to the member of a set by using brackets [ and ]

let Price['Malibu'] := 100;

solve;

display Price['Malibu']: 

or you can access all the variables at once by using the variable name

display Price; 

Return to top

Variable Types

Variables must be one of four types: real (the default), binary (0-1), integer or symbolic. You declare the type of a variable by adding the type keyword after the variable label (or giving no type if it is a real variable).

var <varname> [<type>]; 

Examples

var Build binary;

var Production {SURFBOARDS} integer; 

Real variables can take any real value, binary variables must be either 0 (often meaning false) or 1 (often meaning true), and integer variables can take on any integer value. If a mathematical programme has any binary or integer variables then it is a mixed-integer (non)linear programme and is often more difficult to solve.

Symbolic variables are used to restrict a variable to lie within a set, e.g.,

set VOWELS := {'a', 'e', 'i', 'o', 'u'};

var vowel symbolic in VOWELS; 

so the in must follow the symbolic keyword.

Return to top

Variable Bounds

Both real and integer variables may have lower and upper bounds. For example, in many mathematical programmes variables are assumed to be nonnegative, e.g.,

var Percentage {INGREDIENTS} >= 0;

var Production {SURFBOARDS} integer >= 0; 

Bounds are set by adding them after the variable label:

var  <varname> [>= <lb>] [<= <ub>]; 

Note There are many attributes that may follow a variable declaration. They can be placed in any order and must be separated by either whitespace or commas.

var Percentage {INGREDIENTS} <= 0, >= 100;

var Production {SURFBOARDS} integer >= 0; 

Parameters as Bounds

To use parameters as bounds you first need to define the parameters, then use them when defining the variable, By using defaults you only need to define bounds when necessary:

param lb {FEEDS} default 0; # Could use -Infinity here
param ub {FEEDS} default Infinity;

var Amount {f in FEEDS} >= lb[f] <= ub[f]; # Amount[f] >= 0 for all f by default

data;

param lb :=
  GRAIN 1
;

param ub :=
  GRAIN 10
  PASTURE 6
;

# The amount of grain is between 1 and 10, the amoun tof pasture is <= 6, all amounts are >= 0

Return to top

Initial Values

Often (especially when solving a nonlinear programme) the initial value, i.e., the value the variable has at the start of the solution process, will affect how the mathematical programme solves. In AMPL you can set initial values on variables either when you declare them or dynamically. To set an initial value within a variable declaration simply add an assignment operator := and the required initial value.

var Price := 1; 

To set an initial value dynamically use the let keyword with the assignment operator and required value before solving.

var Price {SURFBOARDS};

let Price['Malibu'] := 1;

let Price['SuperThruster'] := 1;

option solver minos; solve; 

Return to top

Default Values

Another way of setting initial variable values is to set a new default value (otherwise AMPL sets variables to 0 by default). This is done using the default keyword.

var Price {SURFBOARDS} >= 0 default 100; 

You can still change the initial value of the variables using the let keyword, but if you don't they will automatically take on the default value.

var Price {SURFBOARDS} >= 0 default 1;

let Price['Super Thruster'] := 50;

solve; # Price['Malibu'] starts at 100, Price['Super Thruster'] starts at 50 

Return to top

Accessing a Variable

Variable values are accessed by specifying the indices of the variable you want to access within [ and ].

Examples

See Amount below.

# Objective: minimise the cost per (100g) can 

minimize TotalCost: sum {i in INGREDIENTS} Cost[i] * Amount[i];

# Constraints: Meet the nutritional requirements

subject to MeetRequirement {r in REQUIREMENTS}:

  Min[r] <= sum {i in INGREDIENTS} Contributes[i, r] * Amount[i] <= Max[r]; 

Return to top

Examining Variables

You can easily examine the value of a variable using the display command. You can also examine the column of a variable by using the expand keyword.

Return to top

Fixing Values

Once variables have been added to a model you cannot remove them. However, you can set their values and fix them so that their value doesn't change. AMPL will then treat that variable as a parameter with the fixed value.

To fix a variable, use the fix keyword and the variable name.

fix <varname>; 

If you decide that the variable should be considered again, you can unfix the variable.

To stop a variable being fixed, use the unfix keyword and the variable name.

unfix <varname>; 

Consider the Surfboard Production Problem we can fix the Price variables to remove their nonlinearity. This allows us to use CPLEX to find the optimal production levels for different prices and explore the nonlinear objective function of the price variables.

param Objective {1..150, 1..150};

fix Price;

for {p in 1..150 by 1, q in 1..150 by 1} {

  let Price['Malibu'] := p;

  let Price['Super Thruster'] := q;

  option solver cplex;

  solve;

  let Objective[p, q] := TotalProfit;

} 

We can also fix the prices to their rounded values (to the nearest cent) and re-solve to see what effect the rounding has on the solution.

reset;

model surfboard.mod;

data surfboard.dat;

option solver cplex;

let Price['Malibu'] := 100;

let Price['Super Thruster'] := 58.14;

fix Price;

solve;

display Price, Production; 

Return to top

-- MichaelOSullivan - 28 Feb 2008