# Difference: TransportationProblemInAMPL (8 vs. 9)

#### Revision 92019-11-11 - MichaelOSullivan

Line: 1 to 1

 META TOPICPARENT name="AMPLGuide"

# The Transportation Problem in AMPL

## AMPL Formulation

The formulation of the transportation problem is AMPL is a straightforward translation of the mathematical programme for the transportation problem. We will build the file transportation.mod.

The sets and are declared as SUPPLY_NODES and DEMAND_NODES respectively:

set SUPPLY_NODES;
set DEMAND_NODES;


The supply and demand are declared as integer parameters:

param Supply {SUPPLY_NODES} >= 0, integer;
param Demand {DEMAND_NODES} >= 0, integer;


The cost is declared over the SUPPLY_NODES and DEMAND_NODES:

param Cost {SUPPLY_NODES, DEMAND_NODES};


Now, the mathematical programme follows directly:

var Flow {SUPPLY_NODES, DEMAND_NODES} >= 0, integer;

minimize TotalCost:
sum {i in SUPPLY_NODES, j in DEMAND_NODES} Cost[i, j] * Flow[i, j];

subject to UseSupply {i in SUPPLY_NODES}:
sum {j in DEMAND_NODES} Flow[i, j] = Supply[i];

subject to MeetDemand {j in DEMAND_NODES}:
sum {i in SUPPLY_NODES} Flow[i, j] = Demand[j];

Note that we assume the transportation is balanced.

## Adding Bounds

In the main discussion of transportation problems, we saw that adding bounds to the flow variables allowed us to easily either bound the transportation of good from a supply node to a demand node or remove an arc from the problem altogether.

We can add bounds to our AMPL formulation by declaring 2 new parameters with defaults:

param Lower {SUPPLY_NODES, DEMAND_NODES} integer default 0;
param Upper {SUPPLY_NODES, DEMAND_NODES} integer default Infinity;

and adding them to the Flow variable declaration:
var Flow {i in SUPPLY_NODES, j in DEMAND_NODES}
>= Lower[i, j], <= Upper[i, j], integer;


Also, since some arcs no longer exist you should set a default of 0 for Cost (thus you don't have to define costs for non-existent arcs).

param Cost {SUPPLY_NODES, DEMAND_NODES} default 0;


## Balancing Transportation Problems

Balanced transportation models are preferred as there is no confusion about the relational operators for the supply and demand constraints. We can use a script file (transportation.run) to balance any transportation problem automatically:

reset;

model transportation.mod;

param costFromDummy {DEMAND_NODES} default 0;
param costToDummy   {SUPPLY_NODES} default 0;

param difference;

# Add the problem date file here
# e.g., data brewery.dat;

let difference := (sum {s in SUPPLY_NODES} Supply[s])
- (sum {d in DEMAND_NODES} Demand[d]);

if difference > 0 then
{
let DEMAND_NODES := DEMAND_NODES union {'Dummy'};
let Demand['Dummy'] := difference;
let {s in SUPPLY_NODES} Cost[s, 'Dummy'] := costToDummy[s];
}
else if difference < 0 then
{
let SUPPLY_NODES := SUPPLY_NODES union {'Dummy'};
let Supply['Dummy'] := - difference;
let {d in DEMAND_NODES} Cost['Dummy', d] := costFromDummy[d];
}; # else the problem is balanced

# Make sure the problem is balanced
check : sum {s in SUPPLY_NODES} Supply[s] = sum {d in DEMAND_NODES} Demand[d];

option solver cplex;

solve;

display Flow;

Note the check statement to ensure that the balancing has been done properly before solving. Also, note that costToDummy and costFromDummy allow for the definition of costs on any flow from/to a dummy node in the data file.

-- MichaelOSullivan - 02 Apr 2008

Deleted:
<
<
 META FILEATTACHMENT attachment="latex526e21edb215dffbfdb5ee74dd06358b.png" attr="h" comment="" date="1207132191" name="latex526e21edb215dffbfdb5ee74dd06358b.png" stream="GLOB(0xa44d1b8)" tmpFilename="latex526e21edb215dffbfdb5ee74dd06358b.png" user="MichaelOSullivan" version="1" attachment="latex3c99455acbafe055e535fc129b4dd12e.png" attr="h" comment="" date="1207132191" name="latex3c99455acbafe055e535fc129b4dd12e.png" stream="GLOB(0xa456928)" tmpFilename="latex3c99455acbafe055e535fc129b4dd12e.png" user="MichaelOSullivan" version="1" attachment="latexa518db3a714367f452620a2d18e0d61e.png" attr="h" comment="" date="1207132191" name="latexa518db3a714367f452620a2d18e0d61e.png" stream="GLOB(0xa4568f8)" tmpFilename="latexa518db3a714367f452620a2d18e0d61e.png" user="MichaelOSullivan" version="1" attachment="latex57f16e685545faa46af73ecce6b4eb7c.png" attr="h" comment="" date="1207132191" name="latex57f16e685545faa46af73ecce6b4eb7c.png" stream="GLOB(0xa44d5e4)" tmpFilename="latex57f16e685545faa46af73ecce6b4eb7c.png" user="MichaelOSullivan" version="1" attachment="latex15b62f2a4b15b2f0ea551529e221b54f.png" attr="h" comment="" date="1207132191" name="latex15b62f2a4b15b2f0ea551529e221b54f.png" stream="GLOB(0xa44d950)" tmpFilename="latex15b62f2a4b15b2f0ea551529e221b54f.png" user="MichaelOSullivan" version="1"

 META FILEATTACHMENT attachment="transportation.mod" attr="" comment="" date="1207141133" name="transportation.mod" path="transportation.mod" size="1238" stream="transportation.mod" tmpFilename="" user="MichaelOSullivan" version="2" attachment="transportation.run" attr="" comment="" date="1207188773" name="transportation.run" path="transportation.run" size="929" stream="transportation.run" tmpFilename="" user="BaseUserMapping_333" version="2"
Added:
>
>
 META FILEATTACHMENT attachment="latexddfefd6f6e1b023dbc77750dde745f13.png" attr="h" comment="" date="1573440880" name="latexddfefd6f6e1b023dbc77750dde745f13.png" user="MichaelOSullivan" version="1" attachment="latexd58eb835f5dc3ce48118d235a7ed6afa.png" attr="h" comment="" date="1573440880" name="latexd58eb835f5dc3ce48118d235a7ed6afa.png" user="MichaelOSullivan" version="1" attachment="latex5aff540fda60ff1cc43cde3401da45e7.png" attr="h" comment="" date="1573440880" name="latex5aff540fda60ff1cc43cde3401da45e7.png" user="MichaelOSullivan" version="1" attachment="latex5b7238471e85c930c82a09db6ad982d9.png" attr="h" comment="" date="1573440880" name="latex5b7238471e85c930c82a09db6ad982d9.png" user="MichaelOSullivan" version="1" attachment="latexc3a253a845b49f03af40d72efe1dabb9.png" attr="h" comment="" date="1573440881" name="latexc3a253a845b49f03af40d72efe1dabb9.png" user="MichaelOSullivan" version="1"

Copyright © 2008-2023 by the contributing authors. All material on this collaboration platform is the property of the contributing authors.
Ideas, requests, problems regarding TWiki? Send feedback